KeyboardEvent

Привет.

Клавиатура - это хорошо, а две клавиатуры - лучше так что давайте посмотрим, как можно обработать события клавиатуры в ActionScript 3.0. Хотя бы на этом примере:
( Кликните на флеш-файл для получения фокуса )

Эй! Тут не написано какая клавиша нажата!
Как это не написано? Тут же есть поле Key code.

Там какие-то циферки. Как я по ним узнаю, что это за клавиша?
Выучи ASCII таблицу. Каждой клавише соответствует код. Эти коды в качестве констант есть у класса Keyboard, который находится в пакете flash.ui.
То есть можно написать:

switch ( e.keyCode )
{
    case Keyboard.SPACE :
        // Do something
    break;
}

В константе SPACE хранится число 32, но знать это необязательно.

В примере показано, нажата ли клавиша Ctrl или Shift. Как это узнать?
У KeyboardEvent, кроме keyCode, есть логические свойства: shiftKey и ctrlKey.

Также есть свойство - commandKey. Оно поддерживается только в Mac OS, и имеет то же значение, что и ctrlKey в Windows. В примере я его не использовал из-за расовой ненависти к Mac отсутствия Макинтоша для тестирования.

Как узнать нажата клавиша или отпущена?
Для этого существуют два разных слушателя: KeyboardEvent.KEY_DOWN и KeyboardEvent.KEY_UP.

Внимание! Attention! Ахтунг!
Добавить обработчик можно только на stage.
Вру. Кончено же, не только на stage. Еще на Input Text Field, чтобы контролировать что вводит пользователь.

Ага, учту. Давай что ли примерчик сделаем?
Окей.

Добавим 4 Dynamic Text текстовых поля с именами: eventText, shiftPressedText, keyCodeText, ctrlPressedText.

Main.as:

package
{
    import flash.display.MovieClip;
    import flash.events.KeyboardEvent;
    
    public class Main extends MovieClip
    {
        
        public function Main () : void
        {
            this.init();
        }
        
        private function init () : void
        {
            this.stage.addEventListener( KeyboardEvent.KEY_DOWN, keyDownHandler );
            this.stage.addEventListener( KeyboardEvent.KEY_UP, keyUpHandler );
        }
        
        private function keyDownHandler ( e : KeyboardEvent ) : void
        {
            this.eventText.text = "Key Down";
            this.shiftPressedText.text = String( e.shiftKey );
            this.keyCodeText.text = String( e.keyCode);
            this.ctrlPressedText.text = String( e.ctrlKey );
        }
        
        private function keyUpHandler ( e : KeyboardEvent ) : void
        {
            this.eventText.text = "Key Up";
            this.shiftPressedText.text = String( e.shiftKey );
            this.keyCodeText.text = String( e.keyCode);
            this.ctrlPressedText.text = String( e.ctrlKey );
        }
    }
}

Исходник.

Удачи!